;Alan's mouseover script 1a
;This script displays a specified message at the mouse position when the mouse is over a specified area.
;Multiple message/locations can be specified.
;Place the following script in a spot:
ON ENTER
{
moarray GLOBAL
[
;
;****Set message data: [ x_left x_right y_up y_down 0 "message" ]
[ 82 112 10 48 0 "Message 1" ]
[ 260 293 20 54 0 "Message 2" ]
[ 420 458 26 59 0 "Message 3" ]
[ 80 120 106 143 0 "Message 4" ]
[ 260 305 101 149 0 "Message 5" ]
[ 430 465 114 152 0 "Message 6" ]
;***end of spot data***
] moarray =
0 ME SETALARM
}
ON ALARM
{
moarray GLOBAL
0 i =
{ moarray i GET temparray =
MOUSEPOS DUP temparray 2 GET >= SWAP temparray 3 GET <= AND
SWAP DUP temparray 0 GET >= SWAP temparray 1 GET <= AND AND mouseover =
{
{ temparray 0 GET temparray 1 GET + 2 / x =
temparray 2 GET temparray 3 GET + 2 / y =
"@" x ITOA & "," & y ITOA & temparray 5 GET & LOCALMSG
} mouseover IF
mouseover temparray 4 PUT
temparray moarray i PUT
} temparray 4 GET mouseover == NOT IF
i ++
} { i moarray LENGTH < } WHILE
30 ME SETALARM
}